LED matrica i MAX7219
LED matrica 8 × 8 s čipom MAX7219 na Arduinu: multipleksiranje, vlastita funkcija za slanje sa shiftOut(), sličica, animacija i tekst koji klizi

Na kutiji iznad ploče našeg flipera bit će zaslon od četiri LED matrice. Na njemu će igrač vidjeti rezultat, poruke i male animacije. Danas upoznajemo jednu matricu: 64 LED-ice složene u 8 redaka i 8 stupaca.
Kad bi svaka LED-ica imala svoj pin, Arduinu bi trebala 64 pina, a slobodnih ima 18. Zato su LED-ice spojene u matricu, kao prekidači u prošlom poglavlju, a matricom upravlja čip MAX7219. Arduino s njim razgovara preko samo tri žice. Napisat ćemo vlastitu funkciju koja čipu šalje podatke, nacrtat ćemo sličicu u generatoru znakova i oživjeti je animacijom, a na kraju ćemo preko matrice provući i tekst.
Što to znači za fliper?

Na tlocrtu našeg flipera plavim je krugom označena prva od četiri LED matrice na kutiji iznad ploče, a u velikom krugu ista je matrica uvećana. Što znače ostali dijelovi crteža, piše na stranici o fliperu.
- Zaslon flipera čine četiri ovakve matrice, spojene u lanac. Kako se matrice spajaju u lanac, naučit ćemo u sljedećoj lekciji.
- Zaslonom upravlja Uno za prikaz. Za cijeli zaslon trebaju mu samo tri pina, isto kao danas za jednu matricu.
- Isti Uno pokreće i servomotore i zvuk, pa animacija na zaslonu ne smije čekati s
delay(). Sličice ćemo mijenjati smillis(), kao u Vježbi 3. - Rezultat i poruke klizat će preko zaslona kao tekst u Vježbi 4, samo preko četiri matrice umjesto jedne.
- Jedna matrica u kojoj sve LED-ice svijetle najjače troši oko 0,3 A. Zato zaslon u fliperu ne napaja Arduino, nego napajanje od 5 V.
Kako radi LED matrica
U matrici su 64 LED-ice u 8 redaka (R1 do R8) i 8 stupaca (C1 do C8). Sve LED-ice u istom stupcu imaju zajedničku anodu, a sve LED-ice u istom retku zajedničku katodu. Tako matrica ima samo 16 nožica: 8 za redke i 8 za stupce.

LED-ica svijetli kada je njezin stupac uključen, a njezin redak spojen s GND. Na crtežu je uključen redak R2 (plavo) i stupci C2, C3, C6 i C7 (crveno), pa u retku R2 svijetle četiri LED-ice. Ostali redci nisu uključeni, pa u njima ništa ne svijetli.
Koji stupci su uključeni, piše iznad njih: 1 znači uključen, a 0 isključen. Lijevo od redaka isto tako piše napon retka: 1 je 5 V, a 0 je GND. Uključen je samo R2, pa samo on ima 0. Ostali redci su na 1, pa kroz njihove LED-ice ne teče struja. To je osam bitova, dakle jedan bajt: B01100110. Svaki redak matrice opisuje jedan bajt, pa cijelu sličicu opisuje osam bajtova.
Jedan po jedan redak
Što ako uključimo dva retka odjednom, na primjer R2 i R5? Stupci su zajednički, pa bi oba retka pokazala isti uzorak. Dva različita retka ne možemo prikazati istodobno.
Zato se redci pale jedan po jedan: najprije R1 sa svojim uzorkom, zatim R2 sa svojim, i tako do R8, pa opet ispočetka. To se zove multipleksiranje. Isto smo radili s tipkovnicom u lekciji o matrici prekidača, gdje smo je skenirali redak po redak.

Svaki redak svijetli samo osminu vremena, ali čip prođe kroz svih 8 redaka oko 800 puta u sekundi. Oko je za to presporo, pa vidi cijelu sličicu, a ne redke koji se izmjenjuju. Tako rade i mnogi veliki LED zasloni na ulici.
Koliko nožica treba LED matrica 8 × 8, a koliko bi trebala da svaka LED-ica ima svoje dvije nožice?
Čip MAX7219
Arduino bi matricu mogao multipleksirati i sam, ali mu za to treba 16 pinova i on bi cijelo vrijeme morao paliti redak po redak. Kako to izgleda, voditelj može pokazati u neobaveznoj pokaznoj vježbi na kraju lekcije. Taj posao umjesto njega radi čip MAX7219, koji je s matricom na malom modulu:
- Multipleksira matricu sam, oko 800 puta u sekundi.
- Pamti sličicu. Ima osam registara, za svaki redak po jedan, a u svaki stane jedan bajt. Arduino sličicu pošalje jednom, a čip je prikazuje dok ne dobije novu.
- Ograničava struju svih LED-ica jednim otpornikom, R1 na shemi, pa LED-ice ne trebaju svoje otpornike.
- Mijenja svjetlinu u 16 koraka.
Na našem modulu čip i matrica nisu zalemljeni, nego su utaknuti u podnožja. Pokvareni čip ili matrica mogu se zato izvaditi i zamijeniti novima.

MAX7219 je napravljen za zaslone sa sedmerosegmentnim znamenkama, kakve imaju budilice. Zato se njegovi pinovi za redke zovu DIG0 do DIG7 (engleski digit, znamenka), a pinovi za stupce SEG A do SEG G i SEG DP (segment). Na shemi pinovi DIG idu ravno u redke matrice, a pinovi SEG ispod matrice i odozdo u stupce. Na crtežu čipa pinovi nisu poredani kao na samom čipu, nego tako da se linije ne križaju. Pravi broj pina piše uz svaku liniju.
Otpornik R1 određuje koliko struje teče kroz LED-ice. Kondenzatori C1 i C2 uz čip glade napon napajanja: kada se upali cijeli redak LED-ica, struja naglo poraste, a kondenzatori daju dio struje dok je napajanje ne stigne dati.
Kako Arduino šalje podatke
Arduino je s čipom spojen trima žicama:
- DIN (engleski data in): podaci, bit po bit.
- CLK (clock, takt): kaže čipu kada treba pročitati sljedeći bit.
- CS (chip select, odabir čipa): okvir oko poruke. Na čipu se taj pin zove LOAD, a na modulu CS.

Poruka ima 16 bitova. Arduino najprije postavi CS na LOW. Zatim za svaki bit postavi DIN na 0 ili 1 i pošalje jedan impuls na CLK. Na svakom impulsu čip pročita bit s DIN i gurne prethodne bitove jedno mjesto dalje, kao ljude u redu pred blagajnom. Takav spremnik bitova zove se posmačni registar (engleski shift register). Kada je poslano svih 16 bitova, Arduino vrati CS na HIGH, a čip tada pogleda što je stiglo:
- Prvih 8 bitova je adresa: u koji registar čip upisuje podatak.
- Drugih 8 bitova je podatak: što upisuje.
Na dijagramu Arduino šalje adresu 2 i podatak B01100110: u drugom retku neka svijetle LED-ice u stupcima C2, C3, C6 i C7. To je sličica s početka lekcije.
Ovakav način slanja sličan je vezi SPI, koju koriste mnogi čipovi i moduli.
Čip ima i registre koji nisu redci. Ovih šest koristimo:
| Adresa | Registar | Što upisujemo |
|---|---|---|
| 1 do 8 | redci R1 do R8 | koje LED-ice u retku svijetle, jedan bajt |
| 9 | dekodiranje | 0: svaki bit je jedna LED-ica |
| 10 | svjetlina | 0 (najslabije) do 15 (najjače) |
| 11 | broj redaka | 7: svih osam redaka, od 0 do 7 |
| 12 | uključeno | 1: čip radi, 0: matrica je ugašena |
| 15 | test | 1: sve LED-ice svijetle najjače, 0: normalan rad |
Kada dobije napajanje, čip je ugašen, a u registrima redaka može biti bilo što. Zato ga program na početku uvijek postavi: upiše sve registre iz tablice, obriše sve redke i tek ga onda uključi.
Kojih je prvih osam bitova poruke koja upisuje svjetlinu?
00001010. Tih osam bitova čip dobije prvo, a zatim osam bitova svjetline.Materijal
Svaki polaznik dobiva:
- Arduino Uno i USB kabel
- modul s LED matricom 8 × 8 i čipom MAX7219
- pet spojnih žica sa ženskim krajem na jednoj strani i muškim na drugoj (ženski–muški)
Za pokaznu vježbu u Vježbi 1 voditelj treba osciloskop s dva kanala i dvije sonde, mali breadboard i pet spojnih žica muški–muški.
Za neobaveznu pokaznu vježbu na kraju lekcije voditelj treba još jedan Arduino Uno s USB kabelom, LED matricu 8 × 8 bez modula (na primjer 1588BS), osam otpornika od 1 kΩ, potenciometar od 10 kΩ i spojne žice, a za mjerenje i osciloskop sa sondama iz Vježbe 1.
Spoj iz prošle lekcije više nam ne treba: rastavi ga, a dijelove vrati u kutiju.
Pravila za spajanje
- Dok spajamo, Arduino je odspojen s USB kabela.
- VCC ide na 5V, a GND na GND. Zamijeniš li ih, čip se može pokvariti. Prije uključivanja voditelj pregleda spoj.
- Žice idu na ulazni konektor modula, onaj na kojem piše DIN. Na izlaznom konektoru piše DOUT. Na njega se spaja sljedeća matrica u lancu. Ako Arduino spojiš na izlazni konektor, matrica neće raditi.
- Svjetlinu ostavi na 1, kako je u programu. Matrica tada malo troši i ne blješti u oči.
Spajanje
Ženski kraj žice utakni na nožicu modula, a muški u Arduino. Breadboard nam ne treba.
| Nožica modula | VCC | GND | DIN | CS | CLK |
|---|---|---|---|---|---|
| Arduino pin | 5V | GND | D2 | D3 | D4 |

Ulazni konektor je onaj uz čip, s natpisom DIN. Modul okreni tako da je taj konektor s lijeve strane, kao na slici. Tada je sličica uspravna, a u sljedećoj lekciji desno od njega dolazi druga matrica. Čip ne zna kako modul stoji: njegov redak R1 uvijek je uz isti rub matrice. Okreneš li modul drukčije, okrene se i sličica, a kada je konektor dolje, redci postanu stupci.
Vježba 1: Prva LED-ica
Program
Program postavi čip i upali jednu LED-icu, gornju lijevu. Cijeli razgovor s čipom je u vlastitoj funkciji posalji(), koja šalje jednu poruku: adresu i podatak.
// C++
const int DIN = 2; // podaci
const int CS = 3; // okvir poruke (na čipu LOAD)
const int CLK = 4; // takt
// Adrese registara MAX7219. Adrese 1 do 8 su redci matrice.
const byte DEKODIRANJE = 9; // 0: svaki bit je jedna LED-ica
const byte SVJETLINA = 10; // 0 do 15
const byte BROJ_REDAKA = 11; // 7: svih osam redaka
const byte UKLJUCENO = 12; // 1: radi, 0: ugašen
const byte TEST = 15; // 1: sve LED-ice svijetle, 0: normalan rad
// Šalje čipu jednu poruku: u registar s adresom upiše podatak.
void posalji(byte adresa, byte podatak) {
digitalWrite(CS, LOW); // počinje poruka
shiftOut(DIN, CLK, MSBFIRST, adresa); // prvih 8 bitova: adresa
shiftOut(DIN, CLK, MSBFIRST, podatak); // drugih 8 bitova: podatak
digitalWrite(CS, HIGH); // kraj poruke: čip upiše podatak
}
void setup() {
pinMode(DIN, OUTPUT);
pinMode(CS, OUTPUT);
pinMode(CLK, OUTPUT);
digitalWrite(CS, HIGH); // između poruka CS je HIGH
posalji(TEST, 0); // normalan rad
posalji(DEKODIRANJE, 0); // svaki bit je jedna LED-ica
posalji(BROJ_REDAKA, 7); // svih osam redaka
posalji(SVJETLINA, 1); // slabo svjetlo
for (byte redak = 1; redak <= 8; redak++) {
posalji(redak, 0); // obriši redak
}
posalji(UKLJUCENO, 1); // uključi matricu
posalji(1, B10000000); // redak 1: prva LED-ica slijeva
}
void loop() {
}
Kada je modul spojen, spoji USB kabel i učitaj program. Svijetli li gornja lijeva LED-ica?
Što je novo u programu?
const byte DEKODIRANJE = 9;– Tipbytesprema cijeli broj od 0 do 255, dakle točno osam bitova. Adrese i podaci čipa su bajtovi, pa ih spremamo u taj tip. Registri imaju imena, pa u programu pišemoposalji(SVJETLINA, 1)umjesto nejasnogposalji(10, 1).void posalji(byte adresa, byte podatak)– Vlastita funkcija s dva parametra. Kao funkcije iz lekcije o semaforu, ali kada je pozovemo, u zagradi joj damo dva broja:posalji(1, B10000000). Unutar funkcije prvi broj se zoveadresa, a drugipodatak.shiftOut(DIN, CLK, MSBFIRST, adresa);– Ugrađena funkcija Arduina koja šalje jedan bajt, bit po bit: za svaki bit postavi pinDINi pošalje jedan impuls na pinCLK. Upravo to čip očekuje.MSBFIRST(engleski most significant bit first) znači da najprije šalje najviši bit, onaj krajnji lijevo.B10000000– Binarni broj u programu: slovoBi osam bitova. Bit krajnji lijevo je stupac C1, a bit krajnji desno stupac C8. Isto smo mogli napisati kao128, ali iz binarnog zapisa odmah vidimo koje LED-ice svijetle. Više o binarnim brojevima piše na stranici Binarni, oktalni i heksadecimalni brojevi.for (byte redak = 1; redak <= 8; redak++)– Petlja upiše 0 u svih osam registara redaka, adrese 1 do 8. Brojimo od 1, jer su to adrese registara.loop()je prazan. Sličicu smo poslali jednom, a čip je prikazuje sam.
Isprobaj:
- Upali donju desnu LED-icu:
posalji(8, B00000001); - Upali cijeli četvrti redak:
posalji(4, B11111111); - Upali dvije srednje LED-ice u retku 5.
- Svjetlinu postavi na 0, pa na 15. Vidiš li razliku? Zatim je vrati na 1.
Pozive iz zadataka dopiši na kraj funkcije setup(), ispod prve LED-ice.
Ako sličica nije okrenuta kako treba, pogledaj odjeljak Ako nešto ne radi.
Koji poziv upali dvije srednje LED-ice u retku 5?
posalji(5, B00011000);. Srednje LED-ice su u stupcima C4 i C5, a to su četvrti i peti bit slijeva.Pokazna vježba: poruka na osciloskopu
Ovu pokaznu vježbu radi voditelj, a svi gledaju. Osciloskopom ćemo uhvatiti prvu poruku koju program pošalje čipu i pročitati je bit po bit. Dijelovi našeg osciloskopa i osnovne upute za rad opisani su na stranici Osciloskop.
Štipaljka za masu ide samo na GND
Mase obiju sondi u osciloskopu su međusobno spojene. Kada bi jedna štipaljka bila na GND, a druga na nekom drugom pinu, osciloskop bi taj pin spojio s GND. Bio bi to kratki spoj. Zato obje štipaljke idu na GND, a na pinove idu samo vrhovi sondi.
Priprema:
- Odspoji USB kabel. Žice CLK i DIN voditelj provede preko malog breadboarda, kao u lekciji o matrici prekidača: muški kraj žice s modula utakne u svoj redak breadboarda, a iz istog retka druga žica ide u pin D4 (odnosno D2). U svaki od ta dva retka utakne još jednu kratku žicu, na čiji slobodni kraj zakvači vrh sonde. Još jednom žicom spoji GND Arduina s trećim retkom breadboarda, za mase.
- Vrh sonde kanala CH1 zakvači na CLK, a vrh sonde kanala CH2 na DIN. Obje štipaljke za masu zakvači na redak s GND.
- Prekidač na sondi (1X ili 10X) i postavka sonde u izborniku osciloskopa moraju biti isti, za oba kanala.
- Oba kanala postavi na 2 V po podjeljku. CH1 pomakni u gornju polovicu zaslona, a CH2 u donju.
- Vremensku bazu postavi na 20 µs po podjeljku. Ako cijela poruka ne stane na zaslon, odaberi 50 µs.
- Okidanje: izvor CH1, rastući brid, razina oko 2,5 V, način Single. Osciloskop čeka prvi impuls takta.
- Spoji USB kabel. Program se pokrene, a osciloskop uhvati prvu poruku i zaustavi se.
Izvođenje:
- Brojimo impulse. Koliko impulsa ima CLK u jednoj poruci? Trebalo bi ih biti 16.
- Čitamo bitove. Na svakom impulsu takta pogledaj je li DIN gore (1) ili dolje (0). Prva poruka u programu je
posalji(TEST, 0), pa bi bitovi trebali biti00001111, a zatim00000000. Adresa 15 je binarno00001111. - Ponovo. Voditelj ponovo odabere način Single i pritisne tipku RESET na Arduinu. Program počne ispočetka, a osciloskop opet uhvati istu poruku. Ako uhvati nešto drugo, na primjer smetnju dok se Arduino pokreće, ponovi.
Kako s osciloskopa pročitaš adresu poruke?
00001111 je 15, registar test.Vježba 2: Sličica iz generatora znakova
Sličicu je lakše nacrtati nego napisati u bitovima. Za to imamo generator znakova:
- Otvori generator. Pod Dimenzije matrice odaberi 8 x 8, pod Broj znakova (blok) 1 x 1, a pod Orijentacija Redovi ⇒ bytes (standardno).
- Klikom na polja nacrtaj srce. Generator ispod crteža piše niz od osam bajtova, po jedan za svaki redak.
- Niz kopiraj u program iznad funkcije
posalji()i preimenuj ga izmyChar0usrce.
Program
Program je isti kao u Vježbi 1, s dvije promjene: na početku je niz srce, a nova funkcija prikazi() šalje čipu svih osam redaka sličice.
// C++
const int DIN = 2; // podaci
const int CS = 3; // okvir poruke (na čipu LOAD)
const int CLK = 4; // takt
const byte DEKODIRANJE = 9;
const byte SVJETLINA = 10;
const byte BROJ_REDAKA = 11;
const byte UKLJUCENO = 12;
const byte TEST = 15;
// Sličica iz generatora znakova: jedan bajt za svaki redak, odozgo prema dolje.
byte srce[8] = {
B01100110,
B11111111,
B11111111,
B11111111,
B01111110,
B00111100,
B00011000,
B00000000,
};
void posalji(byte adresa, byte podatak) {
digitalWrite(CS, LOW);
shiftOut(DIN, CLK, MSBFIRST, adresa);
shiftOut(DIN, CLK, MSBFIRST, podatak);
digitalWrite(CS, HIGH);
}
// Šalje čipu svih osam redaka sličice.
void prikazi(byte slika[8]) {
for (byte r = 0; r < 8; r++) {
posalji(r + 1, slika[r]); // redak r iz niza ide u registar r + 1
}
}
void setup() {
pinMode(DIN, OUTPUT);
pinMode(CS, OUTPUT);
pinMode(CLK, OUTPUT);
digitalWrite(CS, HIGH);
posalji(TEST, 0);
posalji(DEKODIRANJE, 0);
posalji(BROJ_REDAKA, 7);
posalji(SVJETLINA, 1);
for (byte redak = 1; redak <= 8; redak++) {
posalji(redak, 0);
}
posalji(UKLJUCENO, 1);
prikazi(srce);
}
void loop() {
}
Što je novo u programu?
byte srce[8] = { ... };– Niz od osam bajtova, kao niz pinova u lekciji o matrici prekidača. Generator iza zadnjeg bajta piše zarez, a C++ to dopušta.void prikazi(byte slika[8])– Niz kao parametar funkcije. Funkcija ne zna koju sličicu prikazuje: kada je pozovemo sprikazi(srce), njezin parametarslikaje nizsrce. Istu funkciju možemo pozvati s bilo kojom sličicom od osam bajtova.posalji(r + 1, slika[r]);– U nizu brojimo od nule, pa je prvi redak sličiceslika[0]. Adrese redaka u čipu počinju od 1, pa šaljemo na adresur + 1.
Isprobaj: u generatoru nacrtaj svoju sličicu, na primjer smješka, početno slovo svog imena ili Creepera iz igre reakcije. Kopiraj niz u program umjesto srca.
Koji element niza srce opisuje donji redak matrice?
srce[7]. U nizu brojimo od nule, pa je osmi, donji redak element 7. Funkcija prikazi() ga šalje na adresu 8.Vježba 3: Srce koje kuca
Sada ćemo sličicu oživjeti: veliko i malo srce izmjenjivat će se dvaput u sekundi, pa će izgledati kao da srce kuca. Između dviju sličica program ne čeka s delay(), nego gleda sat s millis(), kao u lekciji o dva semafora. Tako bi loop() u međuvremenu mogao raditi i druge poslove, kao Uno za prikaz u fliperu.
Program
Program iz Vježbe 2 dobiva dva niza umjesto jednog, dvije varijable i novi loop(). Funkcije posalji() i prikazi() ostaju iste.
// C++
const int DIN = 2; // podaci
const int CS = 3; // okvir poruke (na čipu LOAD)
const int CLK = 4; // takt
const byte DEKODIRANJE = 9;
const byte SVJETLINA = 10;
const byte BROJ_REDAKA = 11;
const byte UKLJUCENO = 12;
const byte TEST = 15;
byte velikoSrce[8] = {
B01100110,
B11111111,
B11111111,
B11111111,
B01111110,
B00111100,
B00011000,
B00000000,
};
byte maloSrce[8] = {
B00000000,
B00000000,
B00100100,
B01111110,
B00111100,
B00011000,
B00000000,
B00000000,
};
const unsigned long RAZMAK = 250; // ms između dviju sličica
unsigned long zadnjaPromjena = 0; // kada se sličica zadnji put promijenila
bool veliko = true; // je li sada prikazano veliko srce
void posalji(byte adresa, byte podatak) {
digitalWrite(CS, LOW);
shiftOut(DIN, CLK, MSBFIRST, adresa);
shiftOut(DIN, CLK, MSBFIRST, podatak);
digitalWrite(CS, HIGH);
}
void prikazi(byte slika[8]) {
for (byte r = 0; r < 8; r++) {
posalji(r + 1, slika[r]);
}
}
void setup() {
pinMode(DIN, OUTPUT);
pinMode(CS, OUTPUT);
pinMode(CLK, OUTPUT);
digitalWrite(CS, HIGH);
posalji(TEST, 0);
posalji(DEKODIRANJE, 0);
posalji(BROJ_REDAKA, 7);
posalji(SVJETLINA, 1);
for (byte redak = 1; redak <= 8; redak++) {
posalji(redak, 0);
}
posalji(UKLJUCENO, 1);
prikazi(velikoSrce);
}
void loop() {
if (millis() - zadnjaPromjena >= RAZMAK) {
zadnjaPromjena = millis();
veliko = !veliko; // promijeni sličicu
if (veliko) {
prikazi(velikoSrce);
} else {
prikazi(maloSrce);
}
}
}
Što je novo u programu?
veliko = !veliko;– Znak!znači ne:!truejefalse, a!falsejetrue. Tako varijabla pri svakoj promjeni prijeđe u suprotnu vrijednost.if (millis() - zadnjaPromjena >= RAZMAK)– Isti uzorak kao u lekciji o dva semafora: oduzimamo zadnje vrijeme od sadašnjeg i gledamo je li prošlo dovoljno. Između dviju promjenaloop()prolazi tisuće puta i odmah izlazi, pa Arduino nije zauzet.- Sličicu šaljemo samo kada se promijeni, četiri puta u sekundi. Između toga čip sam drži sliku i multipleksira matricu.
Eksperiment: multipleksiranje uživo
U setup() promijeni broj redaka sa 7 na 3: posalji(BROJ_REDAKA, 3);. Učitaj program. Čip sada prolazi samo kroz redke R1 do R4, pa donja polovica srca ne svijetli. Gornja polovica svijetli jače: svaki od četiri retka sada svijetli četvrtinu vremena, a ne osminu. Vrati broj redaka na 7.
Broj redaka nikad manji od 3
S manje od četiri retka (broj redaka 0, 1 ili 2) čip svaki redak drži upaljenim tako dugo da se njegov izlaz za redak previše grije. Zato u ovom eksperimentu ne idemo ispod 3.
Zašto gornja polovica srca svijetli jače kada je broj redaka 3?
Vježba 4: Tekst koji klizi
Rezultat i poruke na zaslonu flipera neće stajati na mjestu, nego će klizati zdesna nalijevo, kao natpisi na zaslonima na kolodvoru. Danas ćemo tako preko jedne matrice provući tekst FLIPER.
Kako tekst klizi
Zamisli da je cijeli tekst nacrtan na jednoj dugoj matrici, slovo do slova. Svako slovo široko je pet stupaca, a iza njega je jedan prazan stupac, pa zauzima šest stupaca. Visoko je sedam redaka, a donji redak ostaje prazan.

Naša matrica vidi samo osam stupaca tog teksta (plavi okvir). U svakom koraku program pomakne sve točke za jedan stupac ulijevo: lijevi stupac ispadne s matrice, a zdesna uđe sljedeći stupac teksta (narančasti okvir). Ako se to ponavlja dovoljno brzo, oko vidi tekst koji klizi ulijevo.
U programu je to lakše nego što zvuči. Svaki redak matrice je jedan bajt, a bit krajnji lijevo je stupac C1. Kada sve bitove bajta pomaknemo za jedno mjesto ulijevo, pomakne se cijeli redak. Na prazno mjesto zdesna upišemo točku iz sljedećeg stupca slova.
Program
Program zna samo slova teksta FLIPER i razmak. Sličice slova su u dvodimenzionalnom nizu FONT, svaka u jednom retku programa, a niz ZNAKOVI kaže koja je sličica koje slovo: FONT[1] je slovo E, jer je ZNAKOVI[1] 'E'. Funkcije posalji() i prikazi() iste su kao u prošlim vježbama.
// C++
const int DIN = 2; // podaci
const int CS = 3; // okvir poruke (na čipu LOAD)
const int CLK = 4; // takt
const byte DEKODIRANJE = 9;
const byte SVJETLINA = 10;
const byte BROJ_REDAKA = 11;
const byte UKLJUCENO = 12;
const byte TEST = 15;
const char TEKST[] = "FLIPER "; // razmak na kraju odvaja kraj teksta od početka
// Znakovi koje program zna i njihove sličice, istim redom.
// Svako slovo zauzima pet lijevih stupaca i gornjih sedam redaka.
const char ZNAKOVI[] = " EFILPR";
const byte FONT[][8] = {
{ B00000000, B00000000, B00000000, B00000000, B00000000, B00000000, B00000000, B00000000 }, // razmak
{ B11111000, B10000000, B10000000, B11110000, B10000000, B10000000, B11111000, B00000000 }, // E
{ B11111000, B10000000, B10000000, B11110000, B10000000, B10000000, B10000000, B00000000 }, // F
{ B01110000, B00100000, B00100000, B00100000, B00100000, B00100000, B01110000, B00000000 }, // I
{ B10000000, B10000000, B10000000, B10000000, B10000000, B10000000, B11111000, B00000000 }, // L
{ B11110000, B10001000, B10001000, B11110000, B10000000, B10000000, B10000000, B00000000 }, // P
{ B11110000, B10001000, B10001000, B11110000, B10100000, B10010000, B10001000, B00000000 }, // R
};
const byte SIRINA = 6; // stupaca po slovu: pet za slovo i jedan prazan
const unsigned long RAZMAK = 80; // ms između dvaju koraka
byte ekran[8]; // što je sada na matrici, redak po redak
byte slovo = 0; // koje slovo teksta sada ulazi na matricu
byte stupac = 0; // koji stupac tog slova ulazi sljedeći, 0 do 5
unsigned long zadnjiKorak = 0; // kada se tekst zadnji put pomaknuo
void posalji(byte adresa, byte podatak) {
digitalWrite(CS, LOW);
shiftOut(DIN, CLK, MSBFIRST, adresa);
shiftOut(DIN, CLK, MSBFIRST, podatak);
digitalWrite(CS, HIGH);
}
void prikazi(byte slika[8]) {
for (byte r = 0; r < 8; r++) {
posalji(r + 1, slika[r]);
}
}
// Vraća mjesto znaka u nizu ZNAKOVI. Znak kojeg nema postaje razmak.
byte redniBroj(char znak) {
for (byte i = 0; i < strlen(ZNAKOVI); i++) {
if (ZNAKOVI[i] == znak) {
return i;
}
}
return 0; // razmak je prvi u nizu ZNAKOVI
}
void setup() {
pinMode(DIN, OUTPUT);
pinMode(CS, OUTPUT);
pinMode(CLK, OUTPUT);
digitalWrite(CS, HIGH);
posalji(TEST, 0);
posalji(DEKODIRANJE, 0);
posalji(BROJ_REDAKA, 7);
posalji(SVJETLINA, 1);
for (byte redak = 1; redak <= 8; redak++) {
posalji(redak, 0);
}
posalji(UKLJUCENO, 1);
}
void loop() {
if (millis() - zadnjiKorak >= RAZMAK) {
zadnjiKorak = millis();
byte z = redniBroj(TEKST[slovo]); // koja sličica iz niza FONT
for (byte r = 0; r < 8; r++) {
byte tocka = bitRead(FONT[z][r], 7 - stupac); // točka u retku r i stupcu stupac slova
ekran[r] = (ekran[r] << 1) | tocka; // redak ide korak ulijevo, a zdesna ulazi nova točka
}
prikazi(ekran);
stupac++; // sljedeći put ulazi sljedeći stupac
if (stupac == SIRINA) { // slovo je cijelo ušlo
stupac = 0;
slovo++;
if (slovo == strlen(TEKST)) { // ušao je cijeli tekst
slovo = 0;
}
}
}
}
Učitaj program. Klizi li FLIPER preko matrice zdesna nalijevo, pa opet ispočetka?
Što je novo u programu?
const char TEKST[] = "FLIPER ";– Tekst u dvostrukim navodnicima je niz znakova tipachar, po jedan za svako slovo:TEKST[0]je'F', aTEKST[1]'L'. Uglate zagrade su prazne, jer C++ sam izbroji koliko mjesta treba. Razmak na kraju je prazno slovo između kraja teksta i njegova sljedećeg početka.strlen(TEKST)– Ugrađena funkcija koja vrati koliko znakova ima tekst: 7, s razmakom (engleski string length, duljina teksta).const byte FONT[][8]– Dvodimenzionalni niz, kaoznakovi[4][4]u lekciji o matrici prekidača. Svaki redak niza je sličica jednog znaka, osam bajtova. Zbirka sličica slova zove se font.FONT[1][0]je gornji redak slova E.byte redniBroj(char znak)– Vlastita funkcija koja vraća vrijednost, kaogetKey()u lekciji o matrici prekidača. Prolazi kroz nizZNAKOVIi vrati mjesto na kojem je pronašla znak. Ako znaka nema, vrati 0, pa se umjesto njega pojavi razmak.bitRead(FONT[z][r], 7 - stupac)– Ugrađena funkcijabitRead(broj, n)vrati bitnbroja: 0 ili 1. Bitove broji zdesna, od nule, pa je stupac krajnji lijevo bit 7. Zato stupac slovastupacčitamo kao bit7 - stupac.ekran[r] << 1– Znak<<pomakne sve bitove za jedno mjesto ulijevo:B11000011 << 1spremljeno u bajt jeB10000110. Bit krajnji lijevo ispadne, jer bajt ima samo osam mjesta, a zdesna uđe 0.| tocka– Znak|(ili) postavi zadnji bit na 1 ako jetocka1:B10000110 | 1jeB10000111. Ako jetocka0, bajt ostane isti. Tako redak ode korak ulijevo, a zdesna uđe nova točka.byte ekran[8];– Ono što je sada na matrici, redak po redak. Na početku su u nizu same nule, pa je matrica prazna, a tekst u nju ulazi zdesna.stupacislovo– Rade kao kazaljke na satu:stupacbroji od 0 do 5, a kada dođe do 6, vrati se na 0 islovoide na sljedeće slovo. Kadaslovoprođe cijeli tekst, i ono se vrati na 0.
Tekst se pomakne za jedan stupac svakih 80 ms, dakle 12,5 stupaca u sekundi. Cijeli FLIPER s razmakom ima 7 × 6 = 42 stupca, pa jedan prolaz traje oko 3,4 sekunde.
Isprobaj:
- Postavi
RAZMAKna 40, pa na 200. Koji tekst najlakše pročitaš? - Napiši drugu riječ od slova koja program već zna, na primjer
"FILIP ". - Napiši svoje ime. Slova kojih nema nacrtaj u generatoru znakova, u pet lijevih stupaca i gornjih sedam redaka. Slovo dopiši na kraj niza
ZNAKOVI, a njegovih osam bajtova kao novi redak na kraj nizaFONT, tako da su oba niza istim redom. Generator piše svaki bajt u svoj redak, a u programu mogu biti i u jednom.
Piši velikim slovima: za program je 'a' drukčiji znak od 'A'. Slova Č, Ć, Đ, Š i Ž ne stanu u jedan char, pa ih funkcija redniBroj() ne može pronaći. Umjesto njih u tekst i u niz ZNAKOVI upiši znak koji inače ne koristiš, na primjer '#' za Š, a u nizu FONT na njegovo mjesto nacrtaj Š.
Što je B10110001 << 1 kada ga spremimo u bajt?
B01100010. Svi bitovi pomaknu se za jedno mjesto ulijevo, prva jedinica slijeva ispadne iz bajta, a zdesna uđe 0.Što se dogodi kada u tekst napišeš slovo kojeg nema u nizu ZNAKOVI?
redniBroj() ga ne pronađe i vrati 0, a FONT[0] je razmak. Umjesto tog slova preko matrice proklizi šest praznih stupaca.Pokazna vježba: matrica bez čipa (neobavezna)
Ovu pokaznu vježbu voditelj radi ako ostane vremena. Pokazuje koliko posla MAX7219 skida s Arduina. Ovdje Arduino matricu multipleksira sam, bez čipa, a potenciometrom se bira koliko puta u sekundi prođe kroz svih osam redaka: od 5 puta do najbrže što može.
Spoj

Kao na shemi modula, pinovi redaka idu ravno u redke matrice, a pinovi stupaca preko otpornika ispod matrice i odozdo u stupce. Na crtežu Arduina pinovi nisu poredani kao na samom Arduinu, nego tako da se linije ne križaju.
Redci matrice, njezine katode, spojeni su izravno na pinove D2 do D9. Stupci, anode, spojeni su preko otpornika od 1 kΩ na D10 do D13 i A1 do A4. Analogni pinovi mogu raditi i kao obični digitalni izlazi. Klizač potenciometra spojen je na A0, a njegovi krajevi na 5V i GND, pa Arduino na A0 čita broj od 0 do 1023.
Svaki stupac ima svoj otpornik, pa kroz svaku upaljenu LED-icu teče oko 2,5 mA, bez obzira na to koliko ih u retku svijetli. Pin uključenog retka vodi struju svih LED-ica u retku. Kada svijetli svih osam, to je oko 20 mA, a više od toga pin Arduina ne bi trebao stalno voditi. Zato otpornici ne smiju biti manji od 1 kΩ, a matrica ne može svijetliti jače. Za jače svjetlo trebalo bi još osam tranzistora, koji bi struju redaka vodili umjesto pinova.
| Redak | R1 | R2 | R3 | R4 | R5 | R6 | R7 | R8 |
|---|---|---|---|---|---|---|---|---|
| Nožica matrice | 13 | 3 | 4 | 10 | 6 | 11 | 15 | 16 |
| Arduino pin | D2 | D3 | D4 | D5 | D6 | D7 | D8 | D9 |
| Stupac | C1 | C2 | C3 | C4 | C5 | C6 | C7 | C8 |
|---|---|---|---|---|---|---|---|---|
| Nožica matrice | 5 | 2 | 7 | 1 | 12 | 8 | 14 | 9 |
| Arduino pin, preko 1 kΩ | D10 | D11 | D12 | D13 | A1 | A2 | A3 | A4 |
Matrica je okrenuta za četvrtinu kruga udesno od crteža u podacima proizvođača: gledano sprijeda, nožice 1 do 8, na strani s natpisom 1588BS, lijevo su, a nožica 1 gore. Tada su redci njezine katode, kao na modulu, pa se redak uključuje s LOW, a stupac s HIGH, kao kod čipa MAX7219, i sličice iz ove lekcije vrijede bez promjene. U podacima proizvođača naši su redci zato stupci A do H, a naši stupci redci 7 do 0.
Kako će spoj složiti, odluči voditelj. Neka na redcima R1 i R2 ostavi mjesto na koje se može zakvačiti vrh sonde osciloskopa.
Bez čipa ili s čipom?
| Matrica bez čipa | Modul s čipom MAX7219 | |
|---|---|---|
| Pinova Arduina | 16 od 18 slobodnih | 3 |
| Otpornika | 8 | nijedan (jedan je na modulu) |
| Žica od Arduina do matrice | 16 | 5 |
| Struja kroz LED-icu dok svijetli | oko 2,5 mA | do 40 mA |
| Tko multipleksira | program, cijelo vrijeme | čip, sam |
Kada matrica bez čipa ima smisla?
Kada mikrokontroler ima dovoljno pinova, može multipleksirati u pozadini, a treba mu nešto što MAX7219 ne zna. Primjer je micro:bit. Njegovih 25 LED-ica nema svoj čip: spojene su ravno na pinove mikrokontrolera, koji ih multipleksira sam. U pravilnim razmacima mikrokontroler zastane s programom, prebaci zaslon na sljedeći redak i nastavi program. To se zove prekid (engleski interrupt). Zato program u MakeCodeu ne mora sam paliti redak po redak. Isto bi s prekidom mogao i Arduino, ali bi mu i dalje trebalo 16 pinova.
- Svjetlina svake LED-ice posebno. MAX7219 ima jednu svjetlinu za cijelu matricu. micro:bit svakoj LED-ici može dati njezinu, jer sam određuje koliko dugo koja svijetli.
- LED-ice kao senzor svjetla. micro:bit mjeri svjetlo samim LED-icama zaslona, jer njihove pinove može na trenutak upotrijebiti i za mjerenje. Kroz čip to ne bi mogao.
- Manje dijelova. U uređaju koji se proizvodi u velikim količinama svaki čip manje je ušteda.
Program
// C++
// Matrica bez čipa MAX7219: Arduino sam pali redak po redak.
// Potenciometar na A0 bira koliko puta u sekundi program prođe kroz svih osam redaka.
const int REDCI[8] = {2, 3, 4, 5, 6, 7, 8, 9}; // R1 do R8, katode
const int STUPCI[8] = {10, 11, 12, 13, A1, A2, A3, A4}; // C1 do C8, anode, svaki preko 1 kΩ
const int POTENCIOMETAR = A0;
const int SUM = 3; // za toliko polozaj skače i kada potenciometar miruje
byte srce[8] = {
B01100110,
B11111111,
B11111111,
B11111111,
B01111110,
B00111100,
B00011000,
B00000000,
};
unsigned long brojSlika = 0; // koliko je puta u ovoj sekundi prošao kroz svih 8 redaka
unsigned long zadnjeBrojanje = 0; // kada je zadnji put izbrojio slike
int ispisaniPolozaj = -100; // položaj kod zadnjeg ispisa; -100: još nijedan
unsigned long ispisaniBroj = 0; // zadnji ispisani broj slika
void setup() {
for (int i = 0; i < 8; i++) {
pinMode(REDCI[i], OUTPUT);
digitalWrite(REDCI[i], HIGH); // redak isključen
pinMode(STUPCI[i], OUTPUT);
digitalWrite(STUPCI[i], LOW); // stupac isključen
}
Serial.begin(9600);
}
void loop() {
int polozaj = analogRead(POTENCIOMETAR);
unsigned long trajanjeRetka = 0; // µs; 0: ne čeka, ide najbrže što može
if (polozaj < 1000) {
long slikaUSekundi = map(polozaj, 0, 999, 5, 100);
trajanjeRetka = 1000000 / (slikaUSekundi * 8);
}
for (int r = 0; r < 8; r++) {
for (int s = 0; s < 8; s++) { // stupci, dok su svi redci isključeni; bit 7 je C1
digitalWrite(STUPCI[s], bitRead(srce[r], 7 - s));
}
unsigned long pocetak = micros();
digitalWrite(REDCI[r], LOW); // uključi redak
while (micros() - pocetak < trajanjeRetka) {
// redak svijetli
}
digitalWrite(REDCI[r], HIGH); // isključi redak
}
brojSlika++;
if (millis() - zadnjeBrojanje >= 1000) {
zadnjeBrojanje = millis();
bool pomaknut = abs(polozaj - ispisaniPolozaj) > SUM; // potenciometar pomaknut od zadnjeg ispisa
bool promijenjen = brojSlika != ispisaniBroj; // ili je broj slika drukčiji
if (pomaknut || promijenjen) {
Serial.print("Slika u sekundi: ");
Serial.println(brojSlika);
ispisaniPolozaj = polozaj;
ispisaniBroj = brojSlika;
}
brojSlika = 0;
}
}
Što je novo u programu?
const int STUPCI[8] = {10, 11, 12, 13, A1, A2, A3, A4};– Pinovi redaka i stupaca spremljeni su u nizove, pa ih petlja prođe redom.A1je samo ime pina, kao13.- Program najprije postavi stupce, dok su svi redci isključeni, i tek tada uključi redak. Kada bi se redak uključio prije, na trenutak bi u njemu svijetlio uzorak prethodnog retka, pa bi se na matrici vidjeli blijedi duhovi.
digitalWrite(STUPCI[s], bitRead(srce[r], 7 - s));–bitRead()iz Vježbe 4 pročita jedan bit retka sličice, 1 ili 0, adigitalWrite()ga pošalje na pin stupca. Bit 7 je stupac C1, kao kod čipa MAX7219.map(polozaj, 0, 999, 5, 100)– Potenciometar bira od 5 do 100 slika u sekundi. Kada je okrenut do kraja ipolozajje 1000 ili više,trajanjeRetkaostaje 0, pa program ne čeka: prolazi kroz redke najbrže što može.while (micros() - pocetak < trajanjeRetka)– Petlja koja čeka dok redak svijetli. Kod 100 slika u sekundi redak svijetli 1250 µs, adelay()broji samo cijele milisekunde. Zato čekamo smicros(), kao u lekciji o kuglici.- Svake sekunde program izbroji koliko je puta u toj sekundi prošao kroz svih osam redaka. U Serial Monitor taj broj ispiše ako je potenciometar pomaknut od zadnjeg ispisa ili ako je broj drukčiji od zadnjeg ispisanog, dakle najviše jednom u sekundi. Ako se u sekundi u kojoj okrećeš potenciometar izmiješaju dvije brzine, broj sljedeće sekunde bit će drukčiji, pa se ispiše i točan broj.
abs(polozaj - ispisaniPolozaj) > SUM–abs()vrati broj bez predznaka, pa je svejedno na koju je stranu potenciometar pomaknut.analogRead()i kada potenciometar miruje vrati malo različite brojeve, na primjer 511 pa 513. Zato pomak doSUMne smatramo pomakom.ispisaniPolozajje na početku -100, daleko od svakog položaja. Zato se prvi broj ispiše sekundu nakon pokretanja.
Priprema osciloskopa
Koliko slika u sekundi matrica stvarno dobije, voditelj mjeri osciloskopom, kao u pokaznoj vježbi u Vježbi 1. Serial Monitor pokazuje koliko je slika program sam izbrojio. Osciloskop mjeri napon na pinovima redaka, neovisno o programu, a pokazuje i koliko dugo svaki redak svijetli. Štipaljke za masu i ovdje idu samo na GND.
- Obje štipaljke za masu zakvači na GND. Zatim vrh sonde kanala CH1 zakvači na redak R1 (pin D2), a vrh sonde kanala CH2 na redak R2 (pin D3).
- Prekidač na sondi (1X ili 10X) i postavka sonde u izborniku osciloskopa moraju biti isti, za oba kanala. Oba kanala postavi na 2 V po podjeljku. CH1 pomakni u gornju polovicu zaslona, a CH2 u donju.
- Okidanje: izvor CH1, padajući brid, razina oko 2,5 V, način Auto. Redak se uključuje s
LOW, pa osciloskop okida kada se uključi R1. - Uključi mjerenje frekvencije (Freq) za CH1. R1 se uključi jednom u svakoj slici, pa je njegova frekvencija broj slika u sekundi.

Na slici je potenciometar postavljen na 100 slika u sekundi, a vremenska baza je 2 ms po podjeljku. R1 je na LOW oko 1,25 ms, osminu vremena, a odmah nakon njega isto toliko dugo R2. Od jednog impulsa na CH1 do sljedećeg prođe jedna cijela slika. Osciloskop pokazuje nešto manje od 100 Hz, na slici 95 Hz. Program uz svako čekanje troši vrijeme i na mijenjanje pinova i na čitanje potenciometra, a toga u računu za trajanjeRetka nema. Serial Monitor trebao bi pokazivati isti broj.
Što pokazati
- Otvori Serial Monitor i okreni potenciometar tako da pokazuje 5 slika u sekundi. Svaki redak svijetli 25 ms, pa se vidi kako se redci srca pale jedan po jedan, odozgo prema dolje. To je multipleksiranje, usporeno toliko da ga oko vidi. Na osciloskopu postavi vremensku bazu na 50 ms po podjeljku: R1 je na
LOW25 ms svakih 200 ms, a Freq je oko 5 Hz. Ako slika ne stoji mirno, odaberi način okidanja Normal. - Polako okreći potenciometar. Kod 10 do 20 slika u sekundi srce jako treperi. Negdje oko 50 do 60 slika u sekundi treperenje nestane, iako ga neki krajičkom oka vide i malo iznad toga. Okreći dalje, gotovo do kraja, dok Freq ne pokaže oko 95 Hz, i postavi vremensku bazu na 2 ms po podjeljku. Zaslon je sada kao na slici gore.
- Okreni potenciometar do kraja. Program više ne čeka i Serial Monitor pokazuje više od tisuću slika u sekundi, ali srce je mnogo tamnije. Arduino sada gotovo cijelo vrijeme mijenja stupce dok su svi redci isključeni, a svaki redak svijetli samo nekoliko mikrosekundi. Na osciloskopu postavi vremensku bazu na 100 µs po podjeljku: Freq pokazuje više od tisuću herca, kao Serial Monitor, a impulsi na R1 i R2 tanki su kao igle. Na 2 µs po podjeljku vidi se koliko je impuls kratak: to je cijelo vrijeme u kojem redak svijetli. Brže dakle nije uvijek bolje: slika se mora osvježavati dovoljno brzo da ne treperi, a svaki redak mora svijetliti veći dio svog vremena.
- Vrati potenciometar na oko 100 slika u sekundi. Na kraj
loop()dodajdelay(200);, kao da Arduino radi još nešto, i učitaj program. Srce sada trepće: dok Arduino čeka, nijedan redak ne svijetli. Matrica bez čipa svijetli samo dok je Arduino multipleksira.
MAX7219 radi isto što i ovaj program, oko 800 puta u sekundi, ali sam, svojim sklopovima. Arduinu zato ostaju slobodni pinovi i vrijeme za druge poslove, a u fliperu ih ima mnogo: palice, servomotori i zvuk.
Zašto je srce tamnije kada program ne čeka između redaka?
Ako nešto ne radi
- Ništa ne svijetli ⇒ Jesu li VCC i GND na 5V i GND? Jesu li žice na ulaznom konektoru, onom s natpisom DIN? Idu li DIN, CS i CLK redom na D2, D3 i D4?
- Ne svijetli ništa ili svijetle krive LED-ice, a spoj je dobar ⇒ Matrica je utaknuta u podnožje na modulu. Je li utaknuta do kraja? Ako je bila izvađena i vraćena obrnuto, okreni je za pola kruga.
- Svijetle sve LED-ice, i to jako ⇒ Čip je u testnom načinu, jer poruke stižu krivo. Provjeri jesu li žice DIN, CS i CLK na pravim pinovima ili su zamijenjene.
- Svijetle nasumične LED-ice ⇒ Program ne briše redke prije uključivanja, ili je neka žica labava. Provjeri petlju koja briše redke i žice.
- Sličica je okrenuta za 90° ili naopako ⇒ Je li ulazni konektor lijevo, kao na slici u odjeljku Spajanje? Ako je konektor dolje, prema tebi, sličica je okrenuta za 90°. Ako je konektor lijevo, a sličica i dalje nije uspravna, kod tvog modula redci i stupci matrice spojeni su drukčije: okreći modul dok sličica ne bude uspravna.
- Sličica je zrcaljena, lijevo je desno, a tekst iz Vježbe 4 klizi udesno ⇒ Kod tvog modula stupci su spojeni obrnutim redom. U funkciji
posalji()u drugom pozivushiftOut(), onom za podatak, zamijeniMSBFIRSTsLSBFIRST. Tada se podatak šalje od najnižeg bita. - Svijetli samo dio redaka ⇒ Broj redaka mora biti 7.
- U tekstu nedostaje slovo ⇒ Tog znaka nema u nizu
ZNAKOVI, pa ga program prikaže kao razmak. Je li slovo napisano velikim slovom, kao u nizuZNAKOVI? - Umjesto jednog slova pojavi se drugo ⇒ Nizovi
ZNAKOVIiFONTnisu istim redom. Sličica slova mora biti na istom mjestu u nizuFONTkao slovo u nizuZNAKOVI. - Arduino se ponovo pokreće ili računalo izgubi USB vezu ⇒ Matrica troši previše struje. Smanji svjetlinu.
- Program se ne može učitati ⇒ Provjeri jesu li u Arduino IDE-u odabrani ploča Arduino Uno i pravi port.
Dodatni izazovi
- Kocka. Na D7 spoji tipkalo, kao u lekciji o tipkalima. Na svaki pritisak neka matrica pokaže slučajnu stranu kocke, od jedne do šest točaka. Savjet: šest sličica spremi u dvodimenzionalni niz
byte kocka[6][8], a slučajan broj od 0 do 5 dobiješ srandom(6). - Animacija od više sličica. Nacrtaj u generatoru tri ili četiri sličice koje se mijenjaju jedna za drugom, na primjer lik koji maše.
- Rezultat. U nizove
ZNAKOVIiFONTiz Vježbe 4 dodaj znamenke od 0 do 9 i neka preko matrice klizi rezultat, na primjer"1250 ". Tako će klizati i rezultat na zaslonu flipera. - Svjetlina koja diše. Neka svjetlina polako raste od 0 do 15, pa pada natrag do 0, bez
delay().
Što smo naučili?
- U LED matrici 8 × 8 anode u svakom stupcu i katode u svakom retku spojene su zajedno, pa 64 LED-ice imaju samo 16 nožica.
- Redak matrice opisuje jedan bajt: 1 je upaljena LED-ica, a 0 ugašena. Bit krajnji lijevo je stupac C1.
- Multipleksiranje: redci se pale jedan po jedan, toliko brzo da oko vidi cijelu sličicu.
- Čip MAX7219 multipleksira matricu sam, pamti sličicu, ograničava struju i mijenja svjetlinu.
- Arduino šalje čipu poruke od 16 bitova preko tri žice: DIN za podatke, CLK za takt i CS kao okvir poruke. Prvih 8 bitova je adresa registra, a drugih 8 podatak.
- Ugrađena funkcija
shiftOut()šalje jedan bajt bit po bit, aMSBFIRSTznači da prvo šalje najviši bit. - Tip
bytesprema broj od 0 do 255. Binarni broj u programu pišemo kaoB01100110. - Vlastita funkcija može imati više parametara, a parametar može biti i niz.
- Sličicu nacrtamo u generatoru znakova i kopiramo kao niz od osam bajtova.
- Animacija bez
delay(): sličicu mijenjamo kadamillis()kaže da je prošlo dovoljno vremena, paloop()nije zauzet. - Tekst je niz znakova tipa
char, astrlen()vrati koliko znakova ima. Sličice slova čine font. - Tekst koji klizi: svaki redak s
<<pomaknemo za jedno mjesto ulijevo, a zdesna s|dodamo točku iz sljedećeg stupca slova, koju pročitamo sbitRead().
Mali kviz
1. Zašto u matrici ne možemo istodobno upaliti dva retka s različitim uzorcima?
2. Što je multipleksiranje i zašto ga oko ne vidi?
3. Koje tri žice povezuju Arduino i MAX7219 i čemu služi svaka?
LOW dok poruka traje, a kada se vrati na HIGH, čip upiše podatak u registar.4. Koliko bitova ima jedna poruka čipu i što znače?
5. Što napravi poziv posalji(3, B11111111)?
B11111111, pa u trećem retku svijetli svih osam LED-ica.6. Zašto program na početku briše svih osam redaka prije nego što uključi čip?
7. Zašto loop() u Vježbi 3 ne čeka s delay()?
millis() loop() samo provjeri je li vrijeme za novu sličicu i odmah ide dalje. U fliperu isti Uno uz zaslon pokreće i servomotore i zvuk.